Arduino Serial 與 String 使用經驗 - readBytes

// -*- mode: C++ -*-
#include <SoftwareSerial.h>
#include <RH_RF95.h>
#include <LowPower.h>

// Singleton instance of the radio driver
SoftwareSerial ss(5, 6); // RX,TX
RH_RF95 rf95(ss);

// 輸入命令後，在回應之前，要等一段處理時間
void write_command(char *cmd) {
    Serial.flush();
    delay(10);

    Serial.write(cmd);
    while (true) {
        delay(50);
        if (Serial.available() > 0)
            break;
    }
}

void send_packet(byte *buf, byte *cp) 
{
    uint8_t len = (unsigned int)cp - (unsigned int)buf;
    rf95.send(buf, len);
    rf95.waitPacketSent();
    rf95.waitAvailableTimeout(300);
}

int get_id()
{
    byte buf[RH_RF95_MAX_MESSAGE_LEN];
    byte *cp = buf;
    byte rbuf[2];
    byte c;
    bool fail = false;

    write_command("device_id\n\r");
    while (true) {
        if (Serial.readBytes(rbuf, 1) == 0) {
            continue;
        }
        c = rbuf[0];

        if (c == '>') { // end data
            break;
        }
        else if (c == 'F') { // FAILED
            fail = true;
        }
        if (c >= '0' && c <= '9') // valid char 0-9
            *cp++ = c;
    }
    *cp = 0;

    if (fail || cp == buf)
        return -1;
    return atoi((char*)buf);
}

bool send_sensor_data(char sensor_no)
{
    byte buf[RH_RF95_MAX_MESSAGE_LEN];
    byte *cp = buf;
    byte rbuf[2];
    byte c;
    bool fail = false;
    bool q = false;
    int count_nl;
    char cmd[] = {'s', 'e', 'n', 's', 'o', 'r', '?', '\n', '\r'};

    cmd[6] = sensor_no;
    write_command(cmd);

    count_nl = 0; // 記錄現在是第幾行
    while (true) {
        if (Serial.readBytes(rbuf, 1) == 0) {
            continue;
        }
        c = rbuf[0];

        if (c == '>') { // end data
            break;
        }
        else if (c == 'F') { // FAILED
            fail = true;
        }
        else if (c == '\n') {
            ++count_nl;
        }
        else if (c == '[') { // 單位開始
            q = true;
        }
        else if (c == ']' && q) { // 單位結束
            q = false;
            continue;
        }

        // 代表換行的 \n\r 只留下 \n, 空白字元和單位也不留
        if (c == '\r' || c == ' ' || q)
            continue;

        if (count_nl >= 1) // 第二行開始才是感測資料
            *cp++ = c;
    }
    *cp = 0;
    
    if (fail)
        return false;
    send_packet(buf, cp);
    return true;
}

void serial_up()
{
    Serial.begin(19200);
    Serial.setTimeout(2000);
}

void save_power()
{
    int c;

    Serial.end();
    rf95.sleep(); // wake up by send(), recv() or idle().

    // 本例設定每10分鐘讀取並發送資料
    for (c = 0; c < 74; ++c) { 
        LowPower.powerDown(SLEEP_8S, ADC_OFF, BOD_OFF);
    }
    LowPower.powerDown(SLEEP_4S, ADC_OFF, BOD_OFF);
}

void setup() 
{
    if (!rf95.init()) {
        while(1);
    }
}

void loop()
{
    int device_id;

    serial_up();

    device_id = get_id();
    rf95.setHeaderFrom((uint8_t) device_id);

    send_sensor_data('1');
    send_sensor_data('2');

    save_power();
    return;
}